'asp'에 해당되는 글 4건
- 2007.06.18 ASP 페이지를 엑셀로 변환하기- ASP Convert to Excel
- 2006.08.01 MSSQL 테이블 정의서를 쉽게 만들어보자!! 8
- 2006.07.21 프로시져를 사용하여 자바스크립트 에러 메시지 출력
- 2006.07.20 Request 개체로 넘어오는 값들을 쉽게 알아내고, 코딩하자 2
Written by Ssemi™(semin Seol), www.Ssemi.net
오랜만에 글을 쓰는 것 같습니다. 물론 몇가지 개발한 결과물이 있는데, 차마 이곳에 올리기가 부끄럽기에(!) 조용히 묻어두고 있습니다만 언젠가는 이 곳에 올라오겠지요.
오래간만에 ASP작업을 했습니다.
ASP를 사용해서 페이지를 엑셀 파일로 받고자 할 때, 아래 두 줄의 소스 코드를 통해서 엑셀로 변환을 시킵니다.
페이지 헤더(Header)에 아래 소스 코드를 삽입 시켜서 엑셀파일로 attach 받는 내용이죠.
Response.ContentType = "application/vnd.ms-excel"
Response.AddHeader "Content-Disposition", "attachment; filename=파일이름.xls"
일반적으로 엑셀로 받고자 하는 내용들은 보통 리스팅(Listing)된 출력 자료들이 대부분입니다.
모두 『표 형식』을 기준으로 리스트를 뿌려주게 됩니다.
표 라는 것은 HTML 에서 TABLE 태그를 통해 이뤄집니다.
일반적으로 리스팅을 위한 코드의 구성은
SQL 쿼리 -> 결과값 레코드셋으로 변환 -> 테이블안에 출력의 순서가 됩니다.
여기서 엑셀 출력을 위해서 기존 파일에 위의 두줄의 코드만 추가해도 되겠지만, 좀 더 광범위하게 쓸 수 있도록 엑셀 출력 파일을 만들고자 한번 만들어봤습니다.
여러개의 엑셀 출력을 할 때 이 소스는 큰 도움이 될 것이라고 생각합니다.
중요 포인트는 두곳입니다.
2가지를 특징을 통해 이 코드는 어디에다가 써도 유동적이게 돌아간다는 것입니다.
oCn, oRs는 각자 알맞는 개체명을 사용하도록 하세요.
써 넣고 보니까, 엑셀 작업과 관련되었다기 보다는 HTML의 표(TABLE)에 들어갈 데이터 생성에 도움을 준 것 같군요.
오랜만에 글을 쓰는 것 같습니다. 물론 몇가지 개발한 결과물이 있는데, 차마 이곳에 올리기가 부끄럽기에(!) 조용히 묻어두고 있습니다만 언젠가는 이 곳에 올라오겠지요.
오래간만에 ASP작업을 했습니다.
ASP를 사용해서 페이지를 엑셀 파일로 받고자 할 때, 아래 두 줄의 소스 코드를 통해서 엑셀로 변환을 시킵니다.
페이지 헤더(Header)에 아래 소스 코드를 삽입 시켜서 엑셀파일로 attach 받는 내용이죠.
Response.ContentType = "application/vnd.ms-excel"
Response.AddHeader "Content-Disposition", "attachment; filename=파일이름.xls"
일반적으로 엑셀로 받고자 하는 내용들은 보통 리스팅(Listing)된 출력 자료들이 대부분입니다.
모두 『표 형식』을 기준으로 리스트를 뿌려주게 됩니다.
표 라는 것은 HTML 에서 TABLE 태그를 통해 이뤄집니다.
일반적으로 리스팅을 위한 코드의 구성은
SQL 쿼리 -> 결과값 레코드셋으로 변환 -> 테이블안에 출력의 순서가 됩니다.
여기서 엑셀 출력을 위해서 기존 파일에 위의 두줄의 코드만 추가해도 되겠지만, 좀 더 광범위하게 쓸 수 있도록 엑셀 출력 파일을 만들고자 한번 만들어봤습니다.
여러개의 엑셀 출력을 할 때 이 소스는 큰 도움이 될 것이라고 생각합니다.
중요 포인트는 두곳입니다.
# 테이블 칼럼 타이틀은 배열을 통해 나타냅니다.
# 레코드셋의 칼럼의 갯수 만큼 나타냅니다.
2가지를 특징을 통해 이 코드는 어디에다가 써도 유동적이게 돌아간다는 것입니다.
<%
' Array 인자와 SELECT 순서가 같아야 함
Dim arrMenuName
arrMenuName = Array("아이디", "이름", "주소", "전화번호", "혈액형")
strSQL = "SELECT 아이디, 이름, 주소, 전화번호, 혈액형 FROM 테이블"
SEToRs = oCn.Execute(strSQL,,1)
%>
<html>
<head>
<title>엑셀출력</title>
<metahttp-equiv="content-type" content="text/html; charset=euc-kr" />
</head>
<body>
<table width="100%" border="1" cellspcaing="0" cellpadding="0">
<tr>
<%
' TH 로 bold 와 center를 한번에~
IF isArray(arrMenuName) Then
For i = 0 to UBound(arrMenuName)
Response.Write "<th style=""background:#EEEEEE"">"& arrMenuName(i) & "</th>" & vbCrLF
Next
End IF
%>
</tr>
<tr align="center">
<%
SET oRs = oCn.Execute(strSQL,,1)
IF oRs.State = 1 Then
IF Not oRs.EOF Then
Do While Not oRs.EOF
%>
<tr align="center">
<% For i = 0 to oRs.Fields.Count - 1 ' Recordset Column Count 만큼 TD 생성!!%>
<td><%= oRs(i)%></td>
<% Next %>
</tr>
<%
oRs.MoveNext
Loop
End IF
oRs.Close : SET oRs= Nothing
End IF
%>
</tr>
</table>
</body>
</html>
<%
IF oCn.State = 1 then
oCn.Close
SET oCn = Nothing
End IF
%>
oCn, oRs는 각자 알맞는 개체명을 사용하도록 하세요.
써 넣고 보니까, 엑셀 작업과 관련되었다기 보다는 HTML의 표(TABLE)에 들어갈 데이터 생성에 도움을 준 것 같군요.
의도하고자 하는 바와 정반대의 길을 걷고 있는 군요 ^^;
2007. 06. 18. by Ssemi™
2007. 06. 18. by Ssemi™
2007. 6. 18. 14:44
Written by Ssemi™(semin Seol), www.Ssemi.net
개발자의 필요 덕목 중 개발능력도 물론 중요하지만, 문서화는 매우 중요한 요소입니다.
문서화 능력 하나로 인해 같은 개발능력을 갖고 있는 개발자라 할 지라도, 차이점이 존재하게 만들 수 있기 때문이지요.
Stored Procedure(저장 프로시져) 코딩을 쉽게 하자에 이은 2탄은 바로 테이블 정의서를 쉽게 만들어 보는 것입니다.
사수에게 테이블 정보를 전달 받을 때, 혹은 부사수에게 테이블에 대한 내용을 알려줄때 유용하게 사용하실 수 있습니다.
Document Table List
MSSQL Eterprise Manager의 다이어그램을 출력하기 용의하게 변경한 ASP 스크립트 파일입니다.
▶ 미리보기(Preview)
이곳에서 미리보기 가능합니다 (새창으로 띄우실려면 shift + 마우스 클릭)
▶ 다운로드(Download)
invalid-file▶ 사용법(How to use)
파일을 열어보시면 아래와 같은 부분이 있습니다. 해당 정보를 입력해주세요.'--------------------------------------------------------------------------
' // 사용자 지정 사항
'--------------------------------------------------------------------------
' 디비 연결 - DB Connect
'--------------------------------------------------------------------------
Dim DBSRV, DBName, DBID, DBPW
DBSRV = ""
DBName = ""
DBID = ""
DBPW = ""
'--------------------------------------------------------------------------
' 개인 정보 - Personal Info
'--------------------------------------------------------------------------
ProjectName = "TABLE INFOMATION"
YourName = "Your Name"
'--------------------------------------------------------------------------
' 종이 픽셀 설정 (Default : A4)
PaperHeight = "1010" ' A4용지에 맞는 종이 높이값
'--------------------------------------------------------------------------
▶ 주의사항
- 이 스크립트의 실행은 DBMS가 MSSQL임에 한해 실행되고 보여집니다.
- 인터넷 익스플로러(Internet Explorer) + A4용지에 최적화 되어있습니다
- 파이어폭스(Firefox)에서는 용지 중앙에 아주 알맞게 출력됩니다. (단 테이블이 이쁘질 않음 ㅜ_ㅜ)
- 출력 용지를 변경하실 때에는 IE메뉴 - 파일 - 인쇄 미리보기를 통해 PaperHeight 의 값을 설정해주시고 출력한다면 좀 더 멋진 결과물을 받으실 수 있습니다.
2006. 8. 1. 16:13
Written by Ssemi™(semin Seol), www.Ssemi.net
Request개체로 넘어온 Form-Data 쉽게 알아내기에 이어진 라이브러리 2탄!!
웹개발을 하다보면 서버스크립트인 ASP 이외에도 클라이언트 스크립트인 Javascript의 사용은 필수입니다.
아래와 같은 코드를 보십시오.
<%위와 같이 서버/클라이언트의 구분이 있을 경우에는 코딩이 지저분해지고, 중간중간마다 <% %> 구분을 해주면서 Javascript도 함께 써야 하는 불편함이 있습니다.
'작업 끝! - 커넥션 풀링
IF oCn.State = 1 Then oCn.Close
%>
<script type="text/javascript">
<!--
window.alert('확인 테스트');
document.location.href = '/test.asp';
// -->
</script>
<%
Response.End
%>
바로 이와 같은 코드의 불편함을 줄여주고자 프로시져를 사용하여 에러 메시지를 출력합니다.
아래는 프로시져를 사용하여 변경한 코드입니다.
<%더욱 깔끔한 코드로 만들 수 있습니다. 가독성이 더욱 뛰어나집니다. ^_^
'작업 끝! - 커넥션 풀링
IF oCn.State = 1 Then oCn.Close
FlushError "확인 테스트", "Location", null, "/test.asp"
%>
물론 이와 같은 코드를 모두들 사용하고 계실 것이라 생각합니다.
하지만 선물세트 같이 다용도로 쓰일 수 있게 만든 프로시져라 공개해봅니다 :)
FlushError Procedure
이 프로시져는 서버/클라이언트간에 Javascript 에러 메시지 사용에 있어서 유연한 코딩을 제공해줍니다.
프로시져를 사용함으로서 얻어지는 가독성과 편리함을 느껴보세요 ^_^
▶ 사용법
FlushError 프로시져에는 4가지의 인자(Argument)가 존재합니다.- ErrorText : 에러메시지 출력
- 인자의 값이 Null 이거나 길이가 0 일때는 에러메시지가 나오지 않음
- nOption : 에러메시지 이후의 행동을 명령
- Default Value : Default // history.back() or document.location.href 의 기능을 수행
- Back // history.go(nGo)을 통해 history 이동 가능(일반적으로 history.back()의 기능의 명령)
- Location // document.location.href 를 통해 페이지 이동을 위한 명령
- Close // 현재 창을 닫고 싶을 때 사용
- Opener // 부모창을 이동시키고, 현재 창을 닫는데 사용
- Stop // 아무 반응 없음
- nGo : history.go(#) 안의 인수(#)
- Default Value : -1 // history.back()과 같은 기능
- nPlace : Location.href 를 통해 페이지 이동시에 이동할 위치를 지정
- Default Value : / // Rootpage
▶ 코드
Sub FlushError(ErrorText, nOption, nGo, nPlace)
Response.Write "<script type=""text/javascript"">" & chr(13)
Response.Write "<!-- " & chr(13)
IF Not isNull(ErrorText) And Len(ErrorText) > 0 Then
Response.Write "window.alert('"& ErrorText &"');" & chr(13)
End IF
IF isNull(nOption) OR Len(nOption) = 0 Then nOption = "default"
IF isNull(nGo) OR Not isNumeric(nGo) OR Len(nGo) > 2 OR nGo = 0 Then nGo = "-1"
IF isNull(nPlace) OR Len(nPlace) = 0 OR isNumeric(nPlace) Then nPlace = "/"
Select Case LCase(CSTR(nOption))
Case "back"
Response.Write "history.go("& nGo &");" & chr(13)
Case "location"
Response.Write "document.location.href='"& nPlace &"';" & chr(13)
Case "close"
Response.Write "self.opener = self;" & chr(13)
Response.Write "self.close();" & chr(13)
Case "opener"
Response.Write "if (window.opener && window.opener != null) { " & chr(13)
Response.Write "window.opener.location.href='"& nPlace &"';" & chr(13)
Response.Write "window.close();" & chr(13)
Response.Write "} else { " & chr(13)
Response.Write "window.close();" & chr(13)
Response.Write "}" & chr(13)
Case "default"
Response.Write "if (history.length>0) history.go("& nGo &");" & chr(13)
Response.Write "else document.location.href='"& nPlace &"';" & chr(13)
Case Else
End Select
Response.Write "// --> " & chr(13)
Response.Write "</script>" & chr(13)
Response.End
End Sub
▶ 예제코드
' 테스트1 이라는 에러메시지 출력 후 history.back()기능 수행* nGo, nPlcae 인자는 nOption 에 따라 쓰일 수도, 쓰이지 않을 수도 있음에 유의하여
FlushError "테스트1", "back", -1, 1
' 테스트2 이라는 에러메시지 출력 후 /test.asp 로 이동
FlushError "테스트2", "location", -1, "/test.asp"
' 테스트3 이라는 에러메시지 출력 후 현재 창을 닫음
FlushError "테스트3", "close", -1, 1
' 테스트4 이라는 에러메시지 출력 후 부모창을 /test.asp 로 옮긴 후 현재 창을 닫음
FlushError "테스트4", "opener", -1, "/test.asp"
' 테스트5 이라는 에러메시지 출력 후 멈춤
FlushError "테스트5", "stop", -1, 1
' 에러메시지 없이 /test.asp 로 이동
FlushError "", "Location", -1, "/test.asp"
실제 코딩시에는 FlushError "테스트", "stop", null, null 이라는 명령이 아닌
FlushError "테스트5", "stop", -1, 1 로 쓰게 되면 훨씬 코딩의 이로움이 생깁니다.
도움이 되었길 바라면서 이만 ^_^
2006. 7. 21. 08:29
Written by Ssemi™(semin Seol), www.Ssemi.net
개발자는 코드를 짜면서 재사용이 많은 코드들은 라이브러리로 모아두고 사용하게 됩니다.
지금부터 소개하려는 코드는 ASP를 해오면서 가장 타이핑하기 귀찮았던 form.submit() 시켰을 당시에 Request 개체로 반환되는 Form Data들을 일목요연하게 보여주는 코드가 되겠습니다. ^_^
ASP(Active Server Pages) 웹 개발에서 가장 일반적으로 수행되는 작업 중 하나는 처리를 위해 페이지 간에 데이터를 전달하는 것입니다.
FormData가 보내지는 방식에는 POST, GET의 2가지의 방식이 존재합니다.
Request 개체는 각각의 방식에 따라 Form, QueryString 이라는 컬렉션(Collection)이 존재합니다.
POST 방식으로 보냈을 시에는 Request.Form 을 통해 받게 됩니다.
GET 방식으로 보냈을 시에는 Request.QueryString 을 통해 받게 됩니다.
물론 Request 개체만을 통해서 POST, GET의 구분 없이 받을 수도 있습니다.
다음 예제를 살펴보기로 합시다.- ex1.htmForm, QueryString 으로 구분해 받는 이유중 가장 중요한 2가지는 보안과 구분입니다.
<html>
<head>
<title>FormData GET / POST Example</title>
<meta http-equiv="Content-Type" content="text/html; charset=euc-kr" />
</head>
<body>
<form action="getData.asp" method="GET" id="form1" name="form1">
Name : <input type="text" id="firstName" name="firstName" size="10">
<br>
<input type="submit" value="Submit">
</form>
</body>
</html>
- getData.asp
<%
' method="GET" 방식일 경우
Response.Write Request.QueryString("firstName")
' method="POST" 방식일 경우
Response.Write Request.Form("firstName")
' GET, POST 구분 없이 받을 경우- 컬렉션을 사용안함
Response.Write Request("firstName")
%>
아래 예제는 구분을 보여줍니다- ex2.htm
<html>
<head>
<title>FormData GET / POST Example</title>
<meta http-equiv="Content-Type" content="text/html; charset=euc-kr" />
</head>
<body>
<form action="getData.asp?firstName=test" method="POST" id="form1" name="form1">
Name : <input type="text" id="firstName" name="firstName" size="10">
<br>
<input type="submit" value="Submit">
</form>
</body>
</html>
- getData.asp
<%
Response.Write Request.QueryString("firstName") ' test가 출력
Response.Write "<br />"
Response.Write Request.Form("firstName") ' input text에 입력한 값이 출력
%>
어떤가요? 이해가 조금은 가시는지요? 막간을 이용한 FORM-Data에 대한 설명이었습니다.
자~ 위의 예제에서 느끼게 되는 포스를 느끼게 되었는지요?
<input> 태그를 통해 Form-data로 넘기는 값을 모두 getData.asp 라는 소스파일에서 각각 Request("넘어오는값") 으로 받게 됩니다.
그런데 만약 <input>태그가 10개가 넘어간다면? 혹은 20개, 30개, .......가 된다면??
그럴때 지금부터 설명하는 코드 생성 프로시져가 빛을 발하게 됩니다.
Form-Data Check Procedure
지금부터 설명하는 프로시져는 여러분들의 반복되는 Form-data를 넘기는 과정의 ASP코딩을 한결 쉽고 편하게 도와드릴 것입니다.
본 프로시져는 3개로 구성되어져 있습니다.
- Request.Form Check Procedure
- Request.QueryString Check Procedure
- Request.Cookies Check Procedure
▶ 사용법
아래 코드를 적당한 곳(라이브러리 파일 / 공통 include 함수 파일 등)에 넣어주시고, Request를 써야만 하는 곳.즉, Form-data를 받는 파일(FORM Action="파일이름")에다가 아래 코드를 넣으면 됩니다.
- formchk()
- Response.End
▶ 코드
' Request.Form Check
Sub Formchk()
Dim key
For Each key in Request.Form
Response.Write " Dim " & key & "<BR>"
Next
For Each key in Request.Form
Response.Write key & " = " & "Trim(Request.Form("""& key &""")) " & "<BR>"
Next
Response.Write "<HR>"
For Each key in Request.Form
Response.Write key & " = " & Request.Form(key) & "<BR>"
Next
Response.Write "<HR>"
For Each key in Request.Form
Response.Write key & " = CheckWord(" & key & ")<BR>"
Next
End Sub
' Request.QueryString Check
Sub Querychk()
Dim key
For Each key in Request.QueryString
Response.Write " Dim " & key & "<BR>"
Next
For Each key in Request.QueryString
Response.Write key & " = " & "Trim(Request.QueryString("""& key &""")) " & "<BR>"
Next
Response.Write "<HR>"
For Each key in Request.QueryString
Response.Write key & " = " & Request.QueryString(key) & "<BR>"
Next
Response.Write "<HR>"
For Each key in Request.QueryString
Response.Write key & " = CheckWord(" & key & ")<BR>"
Next
End Sub
' Request.Cookies Check
Sub Cookiechk()
Dim key, dickey
For Each key in Request.Cookies
Response.Write " Dim " & key & "<BR>"
Next
For Each key in Request.Cookies
IF Request.Cookies(key).HasKeys Then
For Each dickey in Request.Cookies(key) '딕셔너리에 있는 모든 키들을 검색하기 위해 또 다른 For Each 를 사용
Response.Write "(" & key & ")(" & dickey & ") = " & Request.Cookies(key)(dickey) & "<BR>"
Next
ELSE
Response.Write key & " = " & Request.Cookies(key) & "<BR>"
End IF
Next
Response.WRite "<HR>"
For Each key in Request.Cookies
IF Request.Cookies(key).HasKeys Then
For Each dickey in Request.Cookies(key)
Response.Write dickey & " = Request.Cookies("""& key &""")("""& dickey &""") " & "<BR>"
Next
ELSE
Response.Write key & " = Request.Cookies("""& key &""")" & "<BR>"
End IF
Next
End Sub
▶ 추가 코드
아래 코드는 문자열 Replace코드입니다. Check Procedure와 같이 쓰입니다Request로 받은 Form-data를 Replace처리합니다.
'CheckWord
Function CheckWord(str)
str = Replace(str, "<", "<")
str = Replace(str, ">", ">")
str = Replace(str, "'", "''")
str = Replace(str, """", Chr(34))
str = Replace(str, "|", Chr(124))
CheckWord = str
End Function
▶ 출력 결과
' Request.Form Check Procedure Execute
Dim userid
Dim password
Dim username
Dim birth_year
Dim birth_month
Dim birth_day
Dim birth_solar
userid = Trim(Request.Form("userid"))
password = Trim(Request.Form("password"))
username = Trim(Request.Form("username"))
birth_year = Trim(Request.Form("birth_year"))
birth_month = Trim(Request.Form("birth_month"))
birth_day = Trim(Request.Form("birth_day"))
birth_solar = Trim(Request.Form("birth_solar"))
userid = ssemi
password = 1234
username = 쎄미
birth_year = 1983
birth_month = 10
birth_day = 6
birth_solar = y
userid = CheckWord(userid)
password = CheckWord(password)
username = CheckWord(username)
birth_year = CheckWord(birth_year)
birth_month = CheckWord(birth_month)
birth_day = CheckWord(birth_day)
birth_solar = CheckWord(birth_solar)
▶ 마치며
어떻습니까? 좀 더 수월하게 좀 더 편하게 코드를 만들 수 있었습니다.물론 이 코드와 비슷한 기능을 하는 프로시져 또는 함수를 구현하신 분이 많으셨으리라 생각합니다.
필요한 부분은 여러분들에 맞게 적절하게 조정해서 써야 하겠습니다.
이 코드들은 실제로 제가 가장 많이 쓰는 프로시져들 중에 하나입니다.
웹개발을 일을 하면서 가장 중요한 것은 시간과의 싸움입니다. ^_^
시스템 프로그램 개발에서 각 코드들을 컴포넌트화 시켜 개발시간을 단축시키는 것과 같이,
웹 개발도 시간을 단축시킬 수 있는 방법을 많이 찾아서 알게 되면 좋겠습니다.
2006. 7. 20. 05:38
Recent comment